Rebol []

laypos: 530x532
laysize: 205x63
do code: [
    boxsize: 8x8 
    texte: head clear find read script "REBOL []" 
    view/options/offset lay: layout [
        origin 0x0 space 0x0 across 
        entarea: area wrap texte laysize 
        at 0x0 movebox: box boxsize green with [feel: make feel [engage: func [face action event] [
                    if action = 'down [face/data: event/offset] 
                    if action = 'up [face/data: none] 
                    if all [face/data find [over away] action] [
                        lay/offset: confine lay/offset + event/offset - face/data face/size 0x0 system/view/screen-face/size 
                        show lay
                    ]
                ]]] 
        at laysize - boxsize sizebox: box boxsize blue with [feel: make feel [engage: func [face action event] [
                    if action = 'down [face/data: event/offset] 
                    if action = 'up [face/data: none] 
                    if all [face/data find [over away] action] [
                        face/offset: face/offset + event/offset - face/data show face 
                        newbox/offset/y: face/offset/y 
                        closebox/offset/x: face/offset/x 
                        lay/size: entarea/size: face/offset + face/size show lay
                    ]
                ]]] 
        at laysize - boxsize * 0x1 newbox: box boxsize yellow [
            if nscript: request-file/only/title/filter "new note name:" "note files" "*.r" [
                nscript: head append clear any [find/last nscript #"." tail nscript] ".r" 
                write nscript rejoin ["REBOL []^/^/laypos: " lay/offset + 20x20 "^/laysize: " lay/size "^/do code: " mold code] 
                launch nscript
            ]
        ] 
        at laysize - boxsize * 1x0 closebox: box boxsize red [write script rejoin [trim/tail entarea/text "^/" "REBOL []^/^/laypos: " lay/offset "^/laysize: " lay/size "^/do code: " mold code] 
            unview
        ] 
        do [focus entarea]
    ] [no-title no-border] laypos
]